Copyright	(c) The University of Glasgow 2001 (c) Jeff Newbern 2003-2007 (c) Andriy Palamarchuk 2007
License	BSD-style (see the file LICENSE)
Maintainer	libraries@haskell.org
Stability	experimental
Portability	portable
Safe Haskell	Safe
Language	Haskell2010

Control.Monad.Cont

Contents

MonadCont class
The Cont monad
The ContT monad transformer
Example 1: Simple Continuation Usage
Example 2: Using callCC
Example 3: Using ContT Monad Transformer

Description

Computation type:: Computations which can be interrupted and resumed.
Binding strategy:: Binding a function to a monadic value creates a new continuation which uses the function as the continuation of the monadic computation.
Useful for:: Complex control structures, error handling, and creating co-routines.
Zero and plus:: None.
Example type:: Cont r a

The Continuation monad represents computations in continuation-passing style (CPS). In continuation-passing style function result is not returned, but instead is passed to another function, received as a parameter (continuation). Computations are built up from sequences of nested continuations, terminated by a final continuation (often id ) which produces the final result. Since continuations are functions which represent the future of a computation, manipulation of the continuation functions can achieve complex manipulations of the future of the computation, such as interrupting a computation in the middle, aborting a portion of a computation, restarting a computation, and interleaving execution of computations. The Continuation monad adapts CPS to the structure of a monad.

Before using the Continuation monad, be sure that you have a firm understanding of continuation-passing style and that continuations represent the best solution to your particular design problem. Many algorithms which require continuations in other languages do not require them in Haskell, due to Haskell's lazy semantics. Abuse of the Continuation monad can produce code that is impossible to understand and maintain.

Synopsis

class Monad m => MonadCont m where
- callCC :: ((a -> m b) -> m a) -> m a
type Cont r = ContT r Identity
cont :: ((a -> r) -> r) -> Cont r a
runCont :: Cont r a -> (a -> r) -> r
mapCont :: (r -> r) -> Cont r a -> Cont r a
withCont :: ((b -> r) -> a -> r) -> Cont r a -> Cont r b
newtype ContT (r :: k) (m :: k -> Type ) a = ContT ((a -> m r) -> m r)
runContT :: ContT r m a -> (a -> m r) -> m r
mapContT :: forall k m (r :: k) a. (m r -> m r) -> ContT r m a -> ContT r m a
withContT :: forall k b m (r :: k) a. ((b -> m r) -> a -> m r) -> ContT r m a -> ContT r m b
module Control.Monad
module Control.Monad.Trans

MonadCont class

class Monad m => MonadCont m where Source #

Methods

callCC :: ((a -> m b) -> m a) -> m a Source #

callCC (call-with-current-continuation) calls a function with the current continuation as its argument. Provides an escape continuation mechanism for use with Continuation monads. Escape continuations allow to abort the current computation and return a value immediately. They achieve a similar effect to throwError and catchError within an Error monad. Advantage of this function over calling return is that it makes the continuation explicit, allowing more flexibility and better control (see examples in Control.Monad.Cont ).

The standard idiom used with callCC is to provide a lambda-expression to name the continuation. Then calling the named continuation anywhere within its scope will escape from the computation, even if it is many layers deep within nested computations.

Instances

Instances details

MonadCont m => MonadCont ( MaybeT m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> MaybeT m b) -> MaybeT m a) -> MaybeT m a Source #
MonadCont m => MonadCont ( ListT m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> ListT m b) -> ListT m a) -> ListT m a Source #
( Monoid w, MonadCont m) => MonadCont ( WriterT w m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> WriterT w m b) -> WriterT w m a) -> WriterT w m a Source #
( Monoid w, MonadCont m) => MonadCont ( WriterT w m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> WriterT w m b) -> WriterT w m a) -> WriterT w m a Source #
MonadCont m => MonadCont ( StateT s m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> StateT s m b) -> StateT s m a) -> StateT s m a Source #
MonadCont m => MonadCont ( StateT s m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> StateT s m b) -> StateT s m a) -> StateT s m a Source #
MonadCont m => MonadCont ( ReaderT r m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> ReaderT r m b) -> ReaderT r m a) -> ReaderT r m a Source #
MonadCont m => MonadCont ( IdentityT m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> IdentityT m b) -> IdentityT m a) -> IdentityT m a Source #
MonadCont m => MonadCont ( ExceptT e m) Source #	Since: 2.2
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> ExceptT e m b) -> ExceptT e m a) -> ExceptT e m a Source #
( Error e, MonadCont m) => MonadCont ( ErrorT e m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> ErrorT e m b) -> ErrorT e m a) -> ErrorT e m a Source #
MonadCont ( ContT r m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> ContT r m b) -> ContT r m a) -> ContT r m a Source #
( Monoid w, MonadCont m) => MonadCont ( RWST r w s m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> RWST r w s m b) -> RWST r w s m a) -> RWST r w s m a Source #
( Monoid w, MonadCont m) => MonadCont ( RWST r w s m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> RWST r w s m b) -> RWST r w s m a) -> RWST r w s m a Source #

The Cont monad

type Cont r = ContT r Identity Source #

Continuation monad. Cont r a is a CPS ("continuation-passing style") computation that produces an intermediate result of type a within a CPS computation whose final result type is r .

The return function simply creates a continuation which passes the value on.

The >>= operator adds the bound function into the continuation chain.

cont :: ((a -> r) -> r) -> Cont r a Source #

Construct a continuation-passing computation from a function. (The inverse of runCont )

runCont Source #

Arguments

:: Cont r a	continuation computation ( `Cont` ).
-> (a -> r)	the final continuation, which produces the final result (often `id` ).
-> r

The result of running a CPS computation with a given final continuation. (The inverse of cont )

mapCont :: (r -> r) -> Cont r a -> Cont r a Source #

Apply a function to transform the result of a continuation-passing computation.

```
runCont (mapCont f m) = f . runCont m
```

withCont :: ((b -> r) -> a -> r) -> Cont r a -> Cont r b Source #

Apply a function to transform the continuation passed to a CPS computation.

```
runCont (withCont f m) = runCont m . f
```

The ContT monad transformer

newtype ContT (r :: k) (m :: k -> Type ) a Source #

The continuation monad transformer. Can be used to add continuation handling to any type constructor: the Monad instance and most of the operations do not require m to be a monad.

ContT is not a functor on the category of monads, and many operations cannot be lifted through it.

Constructors

ContT ((a -> m r) -> m r)

Instances

Instances details

MonadReader r' m => MonadReader r' ( ContT r m) Source #
Instance details Defined in Control.Monad.Reader.Class Methods ask :: ContT r m r' Source # local :: (r' -> r') -> ContT r m a -> ContT r m a Source # reader :: (r' -> a) -> ContT r m a Source #
MonadState s m => MonadState s ( ContT r m) Source #
Instance details Defined in Control.Monad.State.Class Methods get :: ContT r m s Source # put :: s -> ContT r m () Source # state :: (s -> (a, s)) -> ContT r m a Source #
MonadTrans ( ContT r)
Instance details Defined in Control.Monad.Trans.Cont Methods lift :: Monad m => m a -> ContT r m a Source #
Monad ( ContT r m)
Instance details Defined in Control.Monad.Trans.Cont Methods (>>=) :: ContT r m a -> (a -> ContT r m b) -> ContT r m b Source # (>>) :: ContT r m a -> ContT r m b -> ContT r m b Source # return :: a -> ContT r m a Source #
Functor ( ContT r m)
Instance details Defined in Control.Monad.Trans.Cont Methods fmap :: (a -> b) -> ContT r m a -> ContT r m b Source # (<$) :: a -> ContT r m b -> ContT r m a Source #
MonadFail m => MonadFail ( ContT r m)
Instance details Defined in Control.Monad.Trans.Cont Methods fail :: String -> ContT r m a Source #
Applicative ( ContT r m)
Instance details Defined in Control.Monad.Trans.Cont Methods pure :: a -> ContT r m a Source # (<>) :: ContT r m (a -> b) -> ContT r m a -> ContT r m b Source # liftA2 :: (a -> b -> c) -> ContT r m a -> ContT r m b -> ContT r m c Source # (>) :: ContT r m a -> ContT r m b -> ContT r m b Source # (<*) :: ContT r m a -> ContT r m b -> ContT r m a Source #
MonadIO m => MonadIO ( ContT r m)
Instance details Defined in Control.Monad.Trans.Cont Methods liftIO :: IO a -> ContT r m a Source #
MonadCont ( ContT r m) Source #
Instance details Defined in Control.Monad.Cont.Class Methods callCC :: ((a -> ContT r m b) -> ContT r m a) -> ContT r m a Source #

runContT :: ContT r m a -> (a -> m r) -> m r Source #

mapContT :: forall k m (r :: k) a. (m r -> m r) -> ContT r m a -> ContT r m a Source #

Apply a function to transform the result of a continuation-passing computation. This has a more restricted type than the map operations for other monad transformers, because ContT does not define a functor in the category of monads.

runContT (mapContT f m) = f . runContT m

withContT :: forall k b m (r :: k) a. ((b -> m r) -> a -> m r) -> ContT r m a -> ContT r m b Source #

Apply a function to transform the continuation passed to a CPS computation.

runContT (withContT f m) = runContT m . f

module Control.Monad

module Control.Monad.Trans

Example 1: Simple Continuation Usage

Calculating length of a list continuation-style:

calculateLength :: [a] -> Cont r Int
calculateLength l = return (length l)

Here we use calculateLength by making it to pass its result to print :

main = do
  runCont (calculateLength "123") print
  -- result: 3

It is possible to chain Cont blocks with >>= .

double :: Int -> Cont r Int
double n = return (n * 2)

main = do
  runCont (calculateLength "123" >>= double) print
  -- result: 6

Example 2: Using `callCC`

This example gives a taste of how escape continuations work, shows a typical pattern for their usage.

-- Returns a string depending on the length of the name parameter.
-- If the provided string is empty, returns an error.
-- Otherwise, returns a welcome message.
whatsYourName :: String -> String
whatsYourName name =
  (`runCont` id) $ do                      -- 1
    response <- callCC $ \exit -> do       -- 2
      validateName name exit               -- 3
      return $ "Welcome, " ++ name ++ "!"  -- 4
    return response                        -- 5

validateName name exit = do
  when (null name) (exit "You forgot to tell me your name!")

Here is what this example does:

Runs an anonymous Cont block and extracts value from it with (`runCont` id) . Here id is the continuation, passed to the Cont block.
Binds response to the result of the following callCC block, binds exit to the continuation.
Validates name . This approach illustrates advantage of using callCC over return . We pass the continuation to validateName , and interrupt execution of the Cont block from inside of validateName .
Returns the welcome message from the callCC block. This line is not executed if validateName fails.
Returns from the Cont block.

Example 3: Using `ContT` Monad Transformer

ContT can be used to add continuation handling to other monads. Here is an example how to combine it with IO monad:

import Control.Monad.Cont
import System.IO

main = do
  hSetBuffering stdout NoBuffering
  runContT (callCC askString) reportResult

askString :: (String -> ContT () IO String) -> ContT () IO String
askString next = do
  liftIO $ putStrLn "Please enter a string"
  s <- liftIO $ getLine
  next s

reportResult :: String -> IO ()
reportResult s = do
  putStrLn ("You entered: " ++ s)

Action askString requests user to enter a string, and passes it to the continuation. askString takes as a parameter a continuation taking a string parameter, and returning IO () . Compare its signature to runContT definition.

MonadCont class

Instances

The Cont monad

The ContT monad transformer

Instances

Example 1: Simple Continuation Usage

Example 2: Using callCC

Example 3: Using ContT Monad Transformer

Example 2: Using `callCC`

Example 3: Using `ContT` Monad Transformer