| Copyright |
(c) Michael Weber <michael.weber@post.rwth-aachen.de> 2001
(c) Jeff Newbern 2003-2006 (c) Andriy Palamarchuk 2006 |
|---|---|
| License | BSD-style (see the file LICENSE) |
| Maintainer | libraries@haskell.org |
| Stability | experimental |
| Portability | non-portable (multi-parameter type classes) |
| Safe Haskell | Safe |
| Language | Haskell2010 |
Control.Monad.Except
Description
- Computation type:
- Computations which may fail or throw exceptions.
- Binding strategy:
- Failure records information about the cause/location of the failure. Failure values bypass the bound function, other values are used as inputs to the bound function.
- Useful for:
- Building computations from sequences of functions that may fail or using exception handling to structure error handling.
- Example type:
-
EitherString a
The Error monad (also called the Exception monad).
Since: 2.2.1
Synopsis
-
class
Monad
m =>
MonadError
e m | m -> e
where
- throwError :: e -> m a
- catchError :: m a -> (e -> m a) -> m a
- liftEither :: MonadError e m => Either e a -> m a
- newtype ExceptT e (m :: Type -> Type ) a = ExceptT (m ( Either e a))
- type Except e = ExceptT e Identity
- runExceptT :: ExceptT e m a -> m ( Either e a)
- mapExceptT :: (m ( Either e a) -> n ( Either e' b)) -> ExceptT e m a -> ExceptT e' n b
- withExceptT :: forall (m :: Type -> Type ) e e' a. Functor m => (e -> e') -> ExceptT e m a -> ExceptT e' m a
- runExcept :: Except e a -> Either e a
- mapExcept :: ( Either e a -> Either e' b) -> Except e a -> Except e' b
- withExcept :: (e -> e') -> Except e a -> Except e' a
- module Control.Monad
- module Control.Monad.Fix
- module Control.Monad.Trans
Warning
Please do not confuse
ExceptT
and
throwError
with
Exception
/
SomeException
and
catch
, respectively. The latter
are for exceptions built into GHC, by default, and are mostly used from within the IO monad.
They do not interact with the "exceptions" in this package at all. This package allows you
to define a new kind of exception control mechanism which does not necessarily need your code to
be placed in the IO monad.
In short, all "catching" mechanisms in this library will be unable to catch exceptions thrown by functions in the Control.Exception module, and vice-versa.
class Monad m => MonadError e m | m -> e where Source #
The strategy of combining computations that can throw exceptions by bypassing bound functions from the point an exception is thrown to the point that it is handled.
Is parameterized over the type of error information and
the monad type constructor.
It is common to use
as the monad type constructor
for an error monad in which error descriptions take the form of strings.
In that case and many other common cases the resulting monad is already defined
as an instance of the
Either
String
MonadError
class.
You can also define your own error type and/or use a monad type constructor
other than
or
Either
String
.
In these cases you will have to explicitly define instances of the
Either
IOError
MonadError
class.
(If you are using the deprecated
Control.Monad.Error
or
Control.Monad.Trans.Error
, you may also have to define an
Error
instance.)
Methods
throwError :: e -> m a Source #
Is used within a monadic computation to begin exception processing.
catchError :: m a -> (e -> m a) -> m a Source #
A handler function to handle previous errors and return to normal execution. A common idiom is:
do { action1; action2; action3 } `catchError` handler
where the
action
functions can call
throwError
.
Note that
handler
and the do-block must have the same return type.
Instances
liftEither :: MonadError e m => Either e a -> m a Source #
Lifts an
into any
Either
e
.
MonadError
e
do { val <- liftEither =<< action1; action2 }
where
action1
returns an
Either
to represent errors.
Since: 2.2.2
The ExceptT monad transformer
newtype ExceptT e (m :: Type -> Type ) a Source #
A monad transformer that adds exceptions to other monads.
ExceptT
constructs a monad parameterized over two things:
- e - The exception type.
- m - The inner monad.
The
return
function yields a computation that produces the given
value, while
>>=
sequences two subcomputations, exiting on the
first exception.
Instances
mapExceptT :: (m ( Either e a) -> n ( Either e' b)) -> ExceptT e m a -> ExceptT e' n b Source #
Map the unwrapped computation using the given function.
-
runExceptT(mapExceptTf m) = f (runExceptTm)
withExceptT :: forall (m :: Type -> Type ) e e' a. Functor m => (e -> e') -> ExceptT e m a -> ExceptT e' m a Source #
Transform any exceptions thrown by the computation using the given function.
runExcept :: Except e a -> Either e a Source #
Extractor for computations in the exception monad.
(The inverse of
except
).
withExcept :: (e -> e') -> Except e a -> Except e' a Source #
Transform any exceptions thrown by the computation using the given
function (a specialization of
withExceptT
).
module Control.Monad
module Control.Monad.Fix
module Control.Monad.Trans
Example 1: Custom Error Data Type
Here is an example that demonstrates the use of a custom error data type with
the
throwError
and
catchError
exception mechanism from
MonadError
.
The example throws an exception if the user enters an empty string
or a string longer than 5 characters. Otherwise it prints length of the string.
-- This is the type to represent length calculation error.
data LengthError = EmptyString -- Entered string was empty.
| StringTooLong Int -- A string is longer than 5 characters.
-- Records a length of the string.
| OtherError String -- Other error, stores the problem description.
-- Converts LengthError to a readable message.
instance Show LengthError where
show EmptyString = "The string was empty!"
show (StringTooLong len) =
"The length of the string (" ++ (show len) ++ ") is bigger than 5!"
show (OtherError msg) = msg
-- For our monad type constructor, we use Either LengthError
-- which represents failure using Left LengthError
-- or a successful result of type a using Right a.
type LengthMonad = Either LengthError
main = do
putStrLn "Please enter a string:"
s <- getLine
reportResult (calculateLength s)
-- Attempts to calculate length and throws an error if the provided string is
-- empty or longer than 5 characters.
-- (Throwing an error in this monad means returning a 'Left'.)
calculateLength :: String -> LengthMonad Int
calculateLength [] = throwError EmptyString
calculateLength s | len > 5 = throwError (StringTooLong len)
| otherwise = return len
where len = length s
-- Prints result of the string length calculation.
reportResult :: LengthMonad Int -> IO ()
reportResult (Right len) = putStrLn ("The length of the string is " ++ (show len))
reportResult (Left e) = putStrLn ("Length calculation failed with error: " ++ (show e))
Example 2: Using ExceptT Monad Transformer
monad transformer can be used to add error handling to another monad.
Here is an example how to combine it with an
ExceptT
IO
monad:
import Control.Monad.Except
-- An IO monad which can return String failure.
-- It is convenient to define the monad type of the combined monad,
-- especially if we combine more monad transformers.
type LengthMonad = ExceptT String IO
main = do
-- runExceptT removes the ExceptT wrapper
r <- runExceptT calculateLength
reportResult r
-- Asks user for a non-empty string and returns its length.
-- Throws an error if user enters an empty string.
calculateLength :: LengthMonad Int
calculateLength = do
-- all the IO operations have to be lifted to the IO monad in the monad stack
liftIO $ putStrLn "Please enter a non-empty string: "
s <- liftIO getLine
if null s
then throwError "The string was empty!"
else return $ length s
-- Prints result of the string length calculation.
reportResult :: Either String Int -> IO ()
reportResult (Right len) = putStrLn ("The length of the string is " ++ (show len))
reportResult (Left e) = putStrLn ("Length calculation failed with error: " ++ (show e))